Linked Open Data - Early Access

The data on listening experiences and their associated contexts are available as open data for consumption by software applications and by people. They are published using the open standards of Linked Data, such as RDF for representation and SPARQL for querying, and are hosted on data.open.ac.uk.

Quick links

Early access

We are giving application developers the opportunity to mine the Listening Experience Database as it gets populated day by day, as opposed to the more common practice of releasing RDF exports of database once they are complete. We envision that this will help disseminate listening experiences in their early stages and provide an additional source of feedback into what users would like to see represented as part of a listening experience. Please note that this means the ontological model of LED is also in a provisional state and is expected to change in the near future. We will do our best to preserve backwards compatibility with obsolete models.

SPARQL endpoint

LED data can be queried using the standard SPARQL language. The service is available via the SPARQL endpoint of the Open University.

Data are stored on the dataset with name http://data.open.ac.uk/context/led (click on the URL for its description using the VoID vocabulary). You can use this URI if you wish to restrict your queries by means of FROM clauses or GRAPH quad patterns, however this is not mandatory in order to query for LED data (they do respond to simple triple pattern queries).

Data dump

The latest RDF dump of the database (in compressed N-Triple format) is available here.

It is automatically updated every day. Older dumps are not available online for the time being, as they are not intended to be referenced by other data.

Ontologies

The root ontology by which LED data are represented is http://led.kmi.open.ac.uk/ontology. It makes use of the following vocabularies:

In addition, several custom terms are used, which are described by the LED root ontology and its dependencies. These terms are to be considered unstable, as some of them are already scheduled for replacement. Please follow the changes to the core ontology as they come.

For deprecated terms, the ontology contains mappings to the newer model using OWL 2 property chains.

Linked datasets

The current LED dataset also reuses members of the following Linked Data sets:

More to come.

Example queries

Example 1

List all the people who have written about their own listening experiences:

PREFIX led: <http://led.kmi.open.ac.uk/term/>
SELECT DISTINCT ?person
WHERE {
   [] a led:ListeningExperience 
      ; led:is_reported_in/<http://schema.org/author> ?person
      ; <http://purl.org/NET/c4dm/event.owl#agent> ?person
} ORDER BY ?person

Try it out (opens in a new window).

Example 2

Get all the countries where national anthems were performed, and how many times in each country (note: this is a federated query whose results also depend on the DBpedia service: if DBpedia is not responding, the query will return zero. In that case, you may try replacing the DBpedia SPARQL endpoint in the query with <http://factforge.net/sparql>):

PREFIX dbpedia-owl: <http://dbpedia.org/ontology/>
PREFIX event: <http://purl.org/NET/c4dm/event.owl#>
PREFIX mo: <http://purl.org/ontology/mo/> 
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
SELECT ?country (COUNT(DISTINCT ?performance) as ?performances)
WHERE {
   ?performance event:place ?place ; 
   mo:genre <http://dbpedia.org/resource/National_anthem>
   SERVICE SILENT <http://dbpedia.org/sparql> { 
      { ?place dbpedia-owl:country ?country } 
      UNION { ?place a dbpedia-owl:Country BIND(?place as ?country) } 
   }
} GROUP BY ?country limit 200

Try it out (opens in a new window).

Example 3

Find all the listening experiences from the World War I period, that some nurse either participated in, or wrote about:

PREFIX dc: <http://purl.org/dc/terms/>
PREFIX edtf: <http://data.open.ac.uk/edtf/ontology/>
PREFIX edtfdata: <http://data.open.ac.uk/time/edtf/>
PREFIX event: <http://purl.org/NET/c4dm/event.owl#>
PREFIX led: <http://led.kmi.open.ac.uk/term/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX schema: <http://schema.org/>
SELECT DISTINCT ?lexp ?who ?when 
WHERE {
   ?lexp event:time [ rdfs:label ?when ; edtf:century edtfdata:Century.19 ; edtf:yearOfCentury/rdf:value ?yoc ]
   VALUES ?nocc { 
      <http://data.open.ac.uk/led/occupation/nurse> 
      <http://data.open.ac.uk/led/thing/QAIMNS+nurse> 
      <http://data.open.ac.uk/led/thing/VAD+nurse> 
   }
   ?lexp event:agent/(led:is_reported_in/dc:isPartOf*/schema:author) ?nurse
   . ?nurse rdfs:label ?who ; <http://dbpedia.org/ontology/occupation> ?nocc
   FILTER ( ?yoc >= 14 && ?yoc <= 18 )
} 
ORDER BY ?lexp ?nurse

Try it out (opens in a new window).

Licence

The LED dataset, whether accessed via the nightly dump or on data.open.ac.uk, is free for non-commercial use (Note: the licence has changed since the dataset was established). For more information, see http://creativecommons.org/licenses/by-nc-sa/4.0/.

Creative Commons License
This work is licensed under a Creative Commons Attribution-NonCommercial-ShareAlike 4.0 International License.